ntu/completions/_ntu

#compdef ntu

# Zsh completion for ntu (NameToUnix)

_ntu() {
    local curcontext="$curcontext" state line
    typeset -A opt_args

    _arguments -C \
        '(-r --recursive)'{-r,--recursive}'[Process directories recursively]' \
        '(-s --sequence)'{-s,--sequence}'[Use transformation sequence]:sequence:(default lower upper minimal utf-8)' \
        '-L[List available sequences]' \
        '--conf[Use specific configuration file]:config file:_files' \
        '(-n --dry-run --no-changes)'{-n,--dry-run,--no-changes}'[Only preview changes without renaming]' \
        '(-q --quiet)'{-q,--quiet}'[Suppress output]' \
        '(-f --force)'{-f,--force}'[Overwrite existing files]' \
        '*'{-e,--exclude}'[Exclude pattern]:pattern:' \
        '(-v --verbose)'{-v,--verbose}'[Verbose debug output]' \
        '--modify-root[Also rename root directory]' \
        '--special[Process symlinks and special files]' \
        '--no-color[Disable colored output]' \
        '(-h --help)'{-h,--help}'[Print help]' \
        '(-V --version)'{-V,--version}'[Print version]' \
        '*:path:_files'
}

_ntu "$@"